merged with master

contrib/lisp/org-special-blocks.el

@@ -64,13 +64,14 @@ seen.  This is run after a few special cases are taken care of."
 (defun org-special-blocks-convert-latex-special-cookies ()
   "Converts the special cookies into LaTeX blocks."
   (goto-char (point-min))
-  (while (re-search-forward "^ORG-\\(.*\\)-\\(START\\|END\\)$" nil t)
+  (while (re-search-forward "^ORG-\\([^ \t\n]*\\)[ \t]*\\(.*\\)-\\(START\\|END\\)$" nil t)
     (replace-match
-     (if (equal (match-string 2) "START")
-	 (concat "\\begin{" (match-string 1) "}")
+     (if (equal (match-string 3) "START")
+	 (concat "\\begin{" (match-string 1) "}" (match-string 2))
        (concat "\\end{" (match-string 1) "}"))
      t t)))
 
+
 (add-hook 'org-export-latex-after-blockquotes-hook
 	  'org-special-blocks-convert-latex-special-cookies)
 

doc/org.texi

@@ -3346,20 +3346,21 @@ with @code{shift-selection-mode}.  See also the variable
 @itemx C-c / t
 @vindex org-todo-keywords
 View TODO items in a @emph{sparse tree} (@pxref{Sparse trees}).  Folds the
-entire buffer, but shows all TODO items and the headings hierarchy above
-them.  With a prefix argument (or by using @kbd{C-c / T}), search for a
-specific TODO.  You will be prompted for the keyword, and you can also give a
-list of keywords like @code{KWD1|KWD2|...} to list entries that match any one
-of these keywords.  With numeric prefix argument N, show the tree for the Nth
-keyword in the variable @code{org-todo-keywords}.  With two prefix arguments,
-find all TODO and DONE entries.
+entire buffer, but shows all TODO items (with not-DONE state) and the
+headings hierarchy above them.  With a prefix argument (or by using @kbd{C-c
+/ T}), search for a specific TODO.  You will be prompted for the keyword, and
+you can also give a list of keywords like @code{KWD1|KWD2|...} to list
+entries that match any one of these keywords.  With numeric prefix argument
+N, show the tree for the Nth keyword in the variable
+@code{org-todo-keywords}.  With two prefix arguments, find all TODO states,
+both un-done and done.
 @kindex C-c a t
 @item C-c a t
-Show the global TODO list.  Collects the TODO items from all agenda
-files (@pxref{Agenda Views}) into a single buffer.  The new buffer will
-be in @code{agenda-mode}, which provides commands to examine and
-manipulate the TODO entries from the new buffer (@pxref{Agenda
-commands}).  @xref{Global TODO list}, for more information.
+Show the global TODO list.  Collects the TODO items (with not-DONE states)
+from all agenda files (@pxref{Agenda Views}) into a single buffer.  The new
+buffer will be in @code{agenda-mode}, which provides commands to examine and
+manipulate the TODO entries from the new buffer (@pxref{Agenda commands}).
+@xref{Global TODO list}, for more information.
 @kindex S-M-@key{RET}
 @item S-M-@key{RET}
 Insert a new TODO entry below the current one.
@@ -6006,8 +6007,8 @@ as level 1 entries to the beginning or end of the file, respectively.  It may
 also be the symbol @code{date-tree}.  Then, a tree with year on level 1,
 month on level 2 and day on level three will be built in the file, and the
 entry will be filed into the tree under the current date@footnote{If the file
-contains an entry with a @code{DATE_TREE} property, the entire date tree will
-be built under that entry.}
+contains an entry with a @code{DATE_TREE} property (arbitrary value), the
+entire date tree will be built under that entry.}
 
 An optional sixth element specifies the contexts in which the user can select
 the template.  This element can be a list of major modes or a function.
@@ -6869,20 +6870,20 @@ collected into a single place.
 @table @kbd
 @kindex C-c a t
 @item C-c a t
-Show the global TODO list.  This collects the TODO items from all
-agenda files (@pxref{Agenda Views}) into a single buffer.  The buffer is in
-@code{agenda-mode}, so there are commands to examine and manipulate
-the TODO entries directly from that buffer (@pxref{Agenda commands}).
+Show the global TODO list.  This collects the TODO items from all agenda
+files (@pxref{Agenda Views}) into a single buffer.  By default, this lists
+items with a state the is not a DONE state.  The buffer is in
+@code{agenda-mode}, so there are commands to examine and manipulate the TODO
+entries directly from that buffer (@pxref{Agenda commands}).
 @kindex C-c a T
 @item C-c a T
 @cindex TODO keyword matching
 @vindex org-todo-keywords
-Like the above, but allows selection of a specific TODO keyword.  You
-can also do this by specifying a prefix argument to @kbd{C-c a t}.  With
-a @kbd{C-u} prefix you are prompted for a keyword, and you may also
-specify several keywords by separating them with @samp{|} as the boolean OR
-operator.  With a numeric prefix, the nth keyword in
-@code{org-todo-keywords} is selected.
+Like the above, but allows selection of a specific TODO keyword.  You can
+also do this by specifying a prefix argument to @kbd{C-c a t}.  You are
+prompted for a keyword, and you may also specify several keywords by
+separating them with @samp{|} as the boolean OR operator.  With a numeric
+prefix, the nth keyword in @code{org-todo-keywords} is selected.
 @kindex r
 The @kbd{r} key in the agenda buffer regenerates it, and you can give
 a prefix argument to this command to change the selected TODO keyword,
@@ -6944,11 +6945,12 @@ define a custom command for it (@pxref{Agenda dispatcher}).
 @item C-c a M
 @vindex org-tags-match-list-sublevels
 @vindex org-agenda-tags-todo-honor-ignore-options
-Like @kbd{C-c a m}, but only select headlines that are also TODO items and
-force checking subitems (see variable @code{org-tags-match-list-sublevels}).
-To exclude scheduled/deadline items, see the variable
-@code{org-agenda-tags-todo-honor-ignore-options}.  Matching specific TODO
-keywords together with a tags match is also possible, see @ref{Tag searches}.
+Like @kbd{C-c a m}, but only select headlines that are also TODO items in a
+not-DONE state and force checking subitems (see variable
+@code{org-tags-match-list-sublevels}).  To exclude scheduled/deadline items,
+see the variable @code{org-agenda-tags-todo-honor-ignore-options}.  Matching
+specific TODO keywords together with a tags match is also possible, see
+@ref{Tag searches}.
 @end table
 
 The commands available in the tags list are described in @ref{Agenda
@@ -7062,12 +7064,13 @@ different way to test TODO states in a search.  For this, terminate the
 tags/property part of the search string (which may include several terms
 connected with @samp{|}) with a @samp{/} and then specify a Boolean
 expression just for TODO keywords.  The syntax is then similar to that for
-tags, but should be applied with care: for example, a positive
-selection on several TODO keywords cannot meaningfully be combined with
-boolean AND.  However, @emph{negative selection} combined with AND can be
-meaningful.  To make sure that only lines are checked that actually have any
-TODO keyword (resulting in a speed-up), use @kbd{C-c a M}, or equivalently
-start the TODO part after the slash with @samp{!}.  Examples:
+tags, but should be applied with care: for example, a positive selection on
+several TODO keywords cannot meaningfully be combined with boolean AND.
+However, @emph{negative selection} combined with AND can be meaningful.  To
+make sure that only lines are checked that actually have any TODO keyword
+(resulting in a speed-up), use @kbd{C-c a M}, or equivalently start the TODO
+part after the slash with @samp{!}.  Using @kbd{C-c a M} or @samp{/!} will
+not match TODO keywords in a DONE state.  Examples:
 
 @table @samp
 @item work/WAITING
@@ -8307,13 +8310,13 @@ Org mode has rules on how to prepare text for rich export.  This section
 summarizes the markup rules used in an Org-mode buffer.
 
 @menu
-* Structural markup elements::	The basic structure as seen by the exporter
-* Images and tables::		Tables and Images will be included
-* Literal examples::		Source code examples with special formatting
-* Include files::		Include additional files into a document
-* Index entries::
-* Macro replacement::		Use macros to create complex output
-* Embedded LaTeX::		LaTeX can be freely used inside Org documents
+* Structural markup elements::  The basic structure as seen by the exporter
+* Images and tables::           Tables and Images will be included
+* Literal examples::            Source code examples with special formatting
+* Include files::               Include additional files into a document
+* Index entries::               Making an index
+* Macro replacement::           Use macros to create complex output
+* Embedded LaTeX::              LaTeX can be freely used inside Org documents
 @end menu
 
 @node Structural markup elements, Images and tables, Markup, Markup

lisp/org-agenda.el

@@ -3621,7 +3621,7 @@ in `org-agenda-text-search-extra-files'."
 
 ;;;###autoload
 (defun org-todo-list (arg)
-  "Show all TODO entries from all agenda file in a single list.
+  "Show all (not done) TODO entries from all agenda file in a single list.
 The prefix arg can be used to select a specific TODO keyword and limit
 the list to these.  When using \\[universal-argument], you will be prompted
 for a keyword.  A numeric prefix directly selects the Nth keyword in
@@ -4573,7 +4573,7 @@ be skipped."
 	      pos (1- (match-beginning 1))
 	      d2 (org-time-string-to-absolute
 		  (match-string 1) d1 'past
-		  org-agenda-repeating-timestamp-show-all t)
+		  org-agenda-repeating-timestamp-show-all)
 	      diff (- d2 d1)
 	      wdays (if suppress-prewarning
 			(let ((org-deadline-warning-days suppress-prewarning))
@@ -4675,7 +4675,7 @@ FRACTION is what fraction of the head-warning time has passed."
 	      pos (1- (match-beginning 1))
 	      d2 (org-time-string-to-absolute
 		  (match-string 1) d1 'past
-		  org-agenda-repeating-timestamp-show-all t)
+		  org-agenda-repeating-timestamp-show-all)
 	      diff (- d2 d1))
 	(setq pastschedp (and todayp (< diff 0)))
 	;; When to show a scheduled item in the calendar:
@@ -6991,6 +6991,8 @@ The cursor may be at a date in the calendar, or in the Org agenda."
       (org-agenda-do-action '(org-deadline nil org-overriding-default-time)))
      ((equal ans ?r)
       (org-agenda-do-action '(org-remember) t))
+     ((equal ans ?c)
+      (org-agenda-do-action '(org-capture) t))
      ((equal ans ?\ )
       (let ((cw (selected-window)))
 	(org-switch-to-buffer-other-window

lisp/org-capture.el

@@ -0,0 +1,1127 @@
+;;; org-capture.el --- Fast note taking in Org-mode
+
+;; Copyright (C) 2010  Free Software Foundation, Inc.
+
+;; Author: Carsten Dominik <carsten at orgmode dot org>
+;; Keywords: outlines, hypermedia, calendar, wp
+;; Homepage: http://orgmode.org
+;; Version: 6.36trans
+;;
+;; This file is part of GNU Emacs.
+;;
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;;
+;;; Commentary:
+
+;; This file contains an alternaive implementation of the same functionality
+;; that is also provided by org-remember.el.  The implementation is more
+;; streamlined, can produce more target types (e.g. plain list items or
+;; table lines).  Also, it does not use a temporary buffer for editing
+;; the captured entry - instead it uses an indirect buffer that visits
+;; the new entry already in the target buffer (this was an idea by Samuel
+;; Wales).  John Wiegley's excellent `remember.el' is not needed for this
+;; implementation, even though we borrow heavily from its ideas.
+
+;; This implementation heavily draws on ideas by James TD Smith and
+;; Samuel Wales, and, of cause, uses John Wiegley's remember.el as inspiration.
+
+;;; TODO
+
+;; - find a clever way to not always insert an annotation maybe a
+;;   predicate function that can check for conditions for %a to be
+;;   used.  This could be one of the properties.
+
+;; - Should there be plist members that arrange for properties to be
+;;   asked for, like James proposed in his RFC?
+
+;;; Code:
+
+(eval-when-compile
+  (require 'cl))
+(require 'org)
+(require 'org-mks)
+
+(defvar org-capture-clock-was-started nil
+  "Internal flag, noting if the clock was started.")
+
+(defvar org-capture-last-stored-marker (make-marker)
+  "Marker pointing to the entry most recently stored with `org-capture'.")
+
+(defgroup org-capture nil
+  "Options concerning capturing new entries."
+  :tag "Org Capture"
+  :group 'org)
+
+(defcustom org-capture-templates nil
+  "Templates for the creation of new entries.
+
+Each entry is a list with the following items:
+
+keys         The keys that will select the template, as a string, characters
+             only, for example \"a\" for a template to be selected with a
+             single key, or \"bt\" for selection with two keys.  When using
+             several keys, keys using the same prefix key must be together
+             in the list and preceded by a 2-element entry explaining the
+             prefix key, for example
+
+                     (\"b\" \"Templates for marking stuff to buy\")
+
+             Do not use \"C\" as a key, it is reserved for customizing the
+             template variable.
+
+description  A short string describing the template, will be shown during
+             selection.
+
+type         The type of entry.  Valid are:
+               entry       an Org-mode node, with a headline. Will be
+                           filed as the child of the target entry or as
+                           a top-level entry.
+               item        a plain list item, placed in the first plain
+                           list a the target location.
+               checkitem   a checkbox item.  This only differs from the
+                           plain lis item by the default template.
+               table-line  a new line in the first table at target location.
+               plain       text to be inserted as it is.
+
+target       Specification of where the captured item should be placed.
+             In Org-mode files, targets usually define a node.  Entries will
+             become children of this node, other types will be added to the
+             table or list in the body of this node.
+
+             Valid values are:
+
+             (file \"path/to/file\")
+                 Text will be placed at the beginning or end of that file
+
+             (id \"id of existing org entry\")
+                 Filing as child of this entry, or in the body of the entry
+
+             (file+headline \"path/to/file\" \"node headline\")
+                 Fast configuration if the target heading is unique in the file
+
+             (file+olp \"path/to/file\" \"Level 1 heading\" \"Level 2\" ...)
+                 For non-unique headings, the full path is safer
+
+             (file+regexp  \"path/to/file\" \"regexp to find location\")
+
+             (file+datetree \"path/to/file\")
+                 Will create a heading in a date tree.
+
+             (file+function \"path/to/file\" function-finding-location)
+                 A function to find the right location in the file.
+
+             (clock)
+                File to the entry that is currently being clocked.
+
+             (function function-finding-location)
+                Most general way, write your own function to find both
+                file and location.
+
+
+template     The template for creating the capture item.  If you leave this
+             empty, an appropriate default template will be used.  See below
+             for more details.
+
+The rest of the entry is a property list of additional options.  Recognized
+properties are:
+
+ :prepend            Normally new captured information will be appended at
+                     the target location (last child, last table line,
+                     last list item...).  Setting this property will
+                     change that.
+
+ :immediate-finish   When set, do not offer to edit the information, just
+                     file it away immediately.  This makes sense if the
+                     template only needs information that can be added
+                     automatically.
+
+ :empty-lines        Set this to the number of lines the should be inserted
+                     before and after the new item.  Default 0, only common
+                     other value is 1.
+
+ :clock-in           Start the clock in this item.
+
+ :clock-resume       Start the interrupted clock when finishing the capture.
+
+ :unnarrowed         Do not narrow the target buffer, simply show the
+                     full buffer.  Default is to narrow it so that you
+                     only see the new stuff.
+
+The template defined the text to be inserted.  Often then this is an org-mode
+entry (so the first line should start with a star) that will be filed as a
+child of the target headline.  It can also be freely formatted text.
+Furthermore, the following %-escapes will be replaced with content:
+
+  %^{prompt}  Prompt the user for a string and replace this sequence with it.
+              A default value and a completion table ca be specified like this:
+              %^{prompt|default|completion2|completion3|...}
+  %t          time stamp, date only
+  %T          time stamp with date and time
+  %u, %U      like the above, but inactive time stamps
+  %^t         like %t, but prompt for date.  Similarly %^T, %^u, %^U.
+              You may define a prompt like %^{Please specify birthday
+  %n          user name (taken from `user-full-name')
+  %a          annotation, normally the link created with `org-store-link'
+  %i          initial content, copied from the active region.  If %i is
+              indented, the entire inserted text will be indented as well.
+  %c          current kill ring head
+  %x          content of the X clipboard
+  %^C         Interactive selection of which kill or clip to use
+  %^L         Like %^C, but insert as link
+  %k          title of currently clocked task
+  %K          link to currently clocked task
+  %^g         prompt for tags, with completion on tags in target file
+  %^G         prompt for tags, with completion all tags in all agenda files
+  %^{prop}p   Prompt the user for a value for property `prop'
+  %:keyword   specific information for certain link types, see below
+  %[pathname] insert the contents of the file given by `pathname'
+  %(sexp)     evaluate elisp `(sexp)' and replace with the result
+
+  %?          After completing the template, position cursor here.
+
+Apart from these general escapes, you can access information specific to the
+link type that is created.  For example, calling `org-capture' in emails
+or gnus will record the author and the subject of the message, which you
+can access with \"%:author\" and \"%:subject\", respectively.  Here is a
+complete list of what is recorded for each link type.
+
+Link type          |  Available information
+-------------------+------------------------------------------------------
+bbdb               |  %:type %:name %:company
+vm, wl, mh, rmail  |  %:type %:subject %:message-id
+                   |  %:from %:fromname %:fromaddress
+                   |  %:to   %:toname   %:toaddress
+                   |  %:fromto (either \"to NAME\" or \"from NAME\")
+gnus               |  %:group, for messages also all email fields
+w3, w3m            |  %:type %:url
+info               |  %:type %:file %:node
+calendar           |  %:type %:date"
+  :group 'org-capture
+  :type
+  '(repeat
+    (choice :value ("" "" entry (file "~/org/notes.org") "")
+     (list :tag "Multikey description"
+	   (string :tag "Keys       ")
+	   (string :tag "Description"))
+     (list :tag "Template entry"
+	   (string :tag "Keys           ")
+	   (string :tag "Description    ")
+	   (choice :tag "Capture Type   " :value entry
+		   (const :tag "Org entry" entry)
+		   (const :tag "Plain list item" item)
+		   (const :tag "Checkbox item" checkitem)
+		   (const :tag "Plain text" plain)
+		   (const :tag "Table line" table-line))
+	   (choice :tag "Target location"
+		   (list :tag "File"
+			 (const :format "" file)
+			 (file :tag "  File"))
+		   (list :tag "ID"
+			 (const :format "" id)
+			 (string :tag "  ID"))
+		   (list :tag "File & Headline"
+			 (const :format "" file+headline)
+			 (file   :tag "  File    ")
+			 (string :tag "  Headline"))
+		   (list :tag "File & Outline path"
+			 (const :format "" file+olp)
+			 (file   :tag "  File    ")
+			 (repeat :tag "Outline path" :inline t
+				 (string :tag "Headline")))
+		   (list :tag "File & Regexp"
+			 (const :format "" file+regexp)
+			 (file   :tag "  File  ")
+			 (regexp :tag "  Regexp"))
+		   (list :tag "File & Date tree"
+			 (const :format "" file+datetree)
+			 (file :tag "  File"))
+		   (list :tag "File & function"
+			 (const :format "" file+function)
+			 (file :tag "  File    ")
+			 (sexp :tag "  Function"))
+		   (list :tag "Current clocking task"
+			 (const :format "" clock))
+		   (list :tag "Function"
+			 (const :format "" function)
+			 (sexp :tag "  Function")))
+	   (string :tag "Template (opt) ")
+	   (plist :inline t
+		  ;; Give the most common options as checkboxes
+		  :options (((const :format "%v " :prepend) (const t))
+			    ((const :format "%v " :immediate-finish) (const t))
+			    ((const :format "%v " :empty-lines) (const 1))
+			    ((const :format "%v " :clock-in) (const t))
+			    ((const :format "%v " :clock-resume) (const t))
+			    ((const :format "%v " :unnarrowed) (const t))))))))
+
+(defcustom org-capture-before-finalize-hook nil
+  "Hook that is run right before a remember process is finalized.
+The remember buffer is still current when this hook runs."
+  :group 'org-capture
+  :type 'hook)
+
+;;; The property list for keeping information about the capture process
+
+(defvar org-capture-plist nil
+  "Plist for the current capture process, global, to avoid having to pass it.")
+(defvar org-capture-current-plist nil
+  "Local variable holding the plist in a capture buffer.
+This is used to store the plist for use when finishing a capture process.
+Another such process might have changed the global varaible by then.")
+
+(defun org-capture-put (&rest stuff)
+  (while stuff
+    (setq org-capture-plist (plist-put org-capture-plist
+				       (pop stuff) (pop stuff)))))
+(defun org-capture-get (prop &optional local)
+  (plist-get (if local org-capture-current-plist org-capture-plist) prop))
+
+(defun org-capture-member (prop)
+  (plist-get org-capture-plist prop))
+
+;;; The minor mode
+
+(defvar org-capture-mode-map (make-sparse-keymap)
+  "Keymap for org-capture-mode, a minor mode.
+Use this map to set additional keybindings for when Org-mode is used
+for a Remember buffer.")
+
+(defvar org-capture-mode-hook nil
+  "Hook for the minor `org-capture-mode'.")
+
+(define-minor-mode org-capture-mode
+  "Minor mode for special key bindings in a remember buffer."
+  nil " Rem" org-capture-mode-map
+  (org-set-local
+   'header-line-format
+   "Capture buffer.  Finish `C-c C-c', refile `C-c C-w', abort `C-c C-k'.")
+  (run-hooks 'org-capture-mode-hook))
+(define-key org-capture-mode-map "\C-c\C-c" 'org-capture-finalize)
+(define-key org-capture-mode-map "\C-c\C-k" 'org-capture-kill)
+(define-key org-capture-mode-map "\C-c\C-w" 'org-capture-refile)
+
+;;; The main commands
+
+;;;###autoload
+(defun org-capture (&optional goto keys)
+  "Capture something.
+
+This will let you select a template from org-capture-templates, and then
+file new captured information.  The text is immediately inserted at the
+target location, and an indirect buffer is shown where you can edit it.
+Pressing `C-c C-c' brings you back to the previous state of Emacs,
+so that you can continue your work.
+
+When called interactively with a `C-u' prefix argument GOTO, don't capture
+anything, just go to the file/headline where the selected template
+stores its notes.  With a double prefix arg `C-u C-u', go to the last
+note stored.
+
+When called with a `C-0' (zero) prefix, insert a template at point.
+
+Lisp programs can set KEYS to a string associated with a template in
+`org-capture-templates'.  In this case, interactive selection will be
+bypassed."
+  (interactive "P")
+  (cond
+   ((equal goto '(4)) (org-capture-goto-target))
+   ((equal goto '(16)) (org-capture-goto-last-stored))
+   (t
+    ;; set temporary variables that will be needed in
+    ;; `org-select-remember-template'
+    (let* ((orig-buf (current-buffer))
+	   (annotation (org-store-link nil))
+	   (initial (and (org-region-active-p)
+			 (buffer-substring (point) (mark))))
+	   (entry (org-capture-select-template keys)))
+      (if (equal entry "C")
+	  (customize-variable 'org-capture-templates)
+	(org-capture-set-plist entry)
+	(org-capture-put :original-buffer orig-buf :annotation annotation
+			 :initial initial)
+	(org-capture-put :default-time
+			 (or org-overriding-default-time
+			     (org-current-time)))
+	(org-capture-set-target-location)
+	(org-capture-put :template (org-capture-fill-template))
+	(if (equal goto 0)
+	    ;;insert at point
+	    (org-capture-insert-template-here)
+	  (org-capture-place-template)
+	  (if (org-capture-get :immediate-finish)
+	      (org-capture-finalize)
+	    (if (and (org-mode-p)
+		     (org-capture-get :clock-in))
+		(condition-case nil
+		    (progn
+		      (if (org-clock-is-active)
+			  (org-capture-put :interrupted-clock
+					   (copy-marker org-clock-marker)))
+		      (org-clock-in)
+		      (org-set-local 'org-capture-clock-was-started t))
+		  (error
+		   "Could not start the clock in this capture buffer"))))))))))
+
+(defun org-capture-finalize ()
+  "Finalize the capture process."
+  (interactive)
+  (unless (and org-capture-mode
+	       (buffer-base-buffer (current-buffer)))
+    (error "This does not seem to be a capture buffer for Org-mode"))
+
+  (let ((beg (point-min))
+	(end (point-max)))
+    (widen)
+    ;; Make sure that the empty lines after are correct
+    (when (and (> (point-max) end) ; indeed, the buffer was still narrowed
+	       (member (org-capture-get :type 'local)
+		       '(entry item checkitem plain)))
+      (save-excursion
+	(goto-char end)
+	(org-capture-empty-lines-after
+	 (or (org-capture-get :empty-lines 'local) 0))))
+    ;; Postprocessing:  Update Statistics cookies, do the sorting
+    (when (org-mode-p)
+      (save-excursion
+	(when (ignore-errors (org-back-to-heading))
+	  (org-update-parent-todo-statistics)
+	  (org-update-checkbox-count)))
+      ;; FIXME Here we should do the sorting
+      ;; If we have added a table line, maybe recompute?
+      (when (and (eq (org-capture-get :type 'local) 'table-line)
+		 (org-at-table-p))
+	(if (org-table-get-stored-formulas)
+	    (org-table-recalculate 'all) ;; FIXME: Should we iterate???
+	  (org-table-align)))
+      )
+    ;; Store this place as the last one where we stored something
+    ;; Do the marking in the base buffer, so that it makes sense after
+    ;; the indirect buffer has been killed.
+    (let ((pos (point)))
+      (with-current-buffer (buffer-base-buffer (current-buffer))
+	(save-excursion
+	  (save-restriction
+	    (widen)
+	    (goto-char pos)
+	    (bookmark-set "org-capture-last-stored")
+	    (move-marker org-capture-last-stored-marker (point))))))
+    ;; Run the hook
+    (run-hooks 'org-capture-before-finalize-hook)
+    ;; Did we start the clock in this capture buffer?
+    (when (and org-capture-clock-was-started
+	       org-clock-marker (marker-buffer org-clock-marker)
+	       (equal (marker-buffer org-clock-marker) (buffer-base-buffer))
+	       (> org-clock-marker (point-min))
+	       (< org-clock-marker (point-max)))
+      ;; Looks like the clock we started is still running.  Clock out.
+      (let (org-log-note-clock-out) (org-clock-out))
+      (when (and (org-capture-get :clock-resume 'local)
+		 (markerp (org-capture-get :interrupted-clock 'local))
+		 (buffer-live-p (marker-buffer
+				 (org-capture-get :interrupted-clock 'local))))
+	(org-with-point-at (org-capture-get :interrupted-clock 'local)
+	  (org-clock-in))
+	(message "Interrupted clock has been resumed")))
+
+    ;; Kill the indirect buffer
+    (save-buffer)
+    (let ((return-wconf (org-capture-get :return-to-wconf 'local)))
+      (kill-buffer (current-buffer))
+      ;; Restore the window configuration before capture
+      (set-window-configuration return-wconf))))
+
+(defun org-capture-refile ()
+  "Finalize the current capture and then refile the entry.
+Refiling is done from the base buffer, because the indirect buffer is then
+already gone."
+  (interactive)
+  (let ((pos (point)) (base (buffer-base-buffer (current-buffer))))
+    (org-capture-finalize)
+    (save-window-excursion
+      (save-excursion
+	(set-buffer (or base (current-buffer)))
+	(save-excursion
+	  (save-restriction
+	    (widen)
+	    (goto-char pos)
+	    (call-interactively 'org-refile)))))))
+
+(defun org-capture-kill ()
+  "Abort the current capture process."
+  (interactive)
+  ;; FIXME: This does not do the right thing, we need to remove the new stuff
+  ;; By hand it is easy: undo, then kill the buffer
+  (let ((org-note-abort t))
+    (org-capture-finalize)))
+
+(defun org-capture-goto-last-stored ()
+  "Go to the location where the last remember note was stored."
+  (interactive)
+  (org-goto-marker-or-bmk org-capture-last-stored-marker
+			  "org-capture-last-stored")
+  (message "This is the last note stored by a capture process"))
+
+;;; Supporting functions for handling the process
+
+(defun org-capture-set-target-location (&optional target)
+  "Find target buffer and position and store then in the property list."
+  (let ((target-entry-p t))
+    (setq target (or target (org-capture-get :target)))
+    (save-excursion
+      (cond
+       ((eq (car target) 'file)
+	(set-buffer (org-capture-target-buffer (nth 1 target)))
+	(setq target-entry-p nil))
+
+       ((eq (car target) 'id)
+	(let ((loc (org-id-find (nth 1 target))))
+	  (if (not loc)
+	      (error "Cannot find target ID \"%s\"" (nth 1 target))
+	    (set-buffer (org-capture-target-buffer (car loc)))
+	    (goto-char (cdr loc)))))
+
+       ((eq (car target) 'file+headline)
+	(set-buffer (org-capture-target-buffer (nth 1 target)))
+	(let ((hd (nth 2 target)))
+	  (goto-char (point-min))
+	  (if (re-search-forward
+	       (format org-complex-heading-regexp-format (regexp-quote hd))
+	       nil t)
+	      (goto-char (point-at-bol))
+	    (goto-char (point-max))
+	    (or (bolp) (insert "\n"))
+	    (insert "* " hd "\n")
+	    (beginning-of-line 0))))
+
+       ((eq (car target) 'file+olp)
+	(let ((m (org-find-olp (cdr target))))
+	  (set-buffer (marker-buffer m))
+	  (goto-char m)))
+
+       ((eq (car target) 'file+regexp)
+	(set-buffer (org-capture-target-buffer (nth 1 target)))
+	(goto-char (point-min))
+	(if (re-search-forward (nth 1 target) nil t)
+	    (progn
+	      (goto-char (match-beginning 0))
+	      (setq target-entry-p (and (org-mode-p) (org-at-heading-p))))
+	  (kill-buffer (current-buffer))
+	  (error "No match for target regexp in file %s" (nth 1 target))))
+
+       ((eq (car target) 'file+datetree)
+	(set-buffer (org-capture-target-buffer (nth 1 target)))
+	;; Make a date tree entry, with the current date (or yesterday,
+	;; if we are extending dates for a couple of hours)
+	(org-datetree-find-date-create
+	 (calendar-gregorian-from-absolute
+	  (time-to-days
+	   (time-subtract (current-time)
+			  (list 0 (* 3600 org-extend-today-until) 0))))))
+
+       ((eq (car target) 'file+function)
+	(set-buffer (org-capture-target-buffer (nth 1 target)))
+	(funcall (nth 1 target))
+	(setq target-entry-p (and (org-mode-p) (org-at-heading-p))))
+
+       ((eq (car target) 'clock)
+	(if (and (markerp org-clock-hd-marker)
+		 (marker-buffer org-clock-hd-marker))
+	    (progn (set-buffer (org-capture-target-buffer
+				(marker-buffer org-clock-hd-marker)))
+		   (goto-char org-clock-hd-marker))
+	  (error "No running clock that could be used as capture target")))
+
+       (t (error "Invalid capture target specification")))
+
+      (org-capture-put :buffer (current-buffer) :pos (point)
+		       :target-entry-p target-entry-p))))
+
+(defun org-capture-target-buffer (file)
+  "Get a buffer for FILE."
+  (or (org-find-base-buffer-visiting file)
+      (find-file-noselect (expand-file-name file org-directory))))
+
+(defun org-capture-steal-local-variables (buffer)
+  "Install Org-mode local variables"
+  (mapc (lambda (v)
+	  (ignore-errors (org-set-local (car v) (cdr v))))
+	(buffer-local-variables buffer)))
+
+(defun org-capture-place-template ()
+  "Insert the template at the target location, and display the buffer."
+  (org-capture-put :return-to-wconf (current-window-configuration))
+  (delete-other-windows)
+  (org-switch-to-buffer-other-window
+   (org-capture-get-indirect-buffer (org-capture-get :buffer) "CAPTURE"))
+  (show-all)
+  (goto-char (org-capture-get :pos))
+  (org-set-local 'org-capture-target-marker
+		 (move-marker (make-marker) (point)))
+  (let* ((template (org-capture-get :template))
+	 (type (org-capture-get :type)))
+    (case type
+      ((nil entry) (org-capture-place-entry))
+      (table-line (org-capture-place-table-line))
+      (plain (org-capture-place-plain-text))
+      (item  (org-capture-place-item))))
+  (org-capture-mode 1)
+  (org-set-local 'org-capture-current-plist org-capture-plist))
+
+(defun org-capture-place-entry ()
+  "Place the template as a new Org entry."
+  (let* ((txt (org-capture-get :template))
+	 (reversed (org-capture-get :prepend))
+	 (target-entry-p (org-capture-get :target-entry-p))
+	 level beg end)
+    (cond
+     ((not target-entry-p)
+      ;; Insert as top-level entry, either at beginning or at end of file
+      (setq level 1)
+      (if reversed
+	  (progn (goto-char (point-min))
+		 (outline-next-heading))
+	(goto-char (point-max))
+	(or (bolp) (insert "\n"))))
+     (t
+      ;; Insert as a child of the current entry
+      (and (looking-at "\\*+")
+	   (setq level (- (match-end 0) (match-beginning 0))))
+      (setq level (org-get-valid-level (or level 1) 1))
+      (if reversed
+	  (progn
+	    (outline-next-heading)
+	    (or (bolp) (insert "\n")))
+	(org-end-of-subtree t t)
+	(or (bolp) (insert "\n")))))
+    (org-capture-empty-lines-before)
+    (setq beg (point))
+    (org-paste-subtree level txt 'for-yank)
+    (org-capture-empty-lines-after 1)
+    (outline-next-heading)
+    (setq end (point))
+    (org-capture-narrow beg (1- end))
+    (if (re-search-forward "%\\?" end t) (replace-match ""))))
+
+(defun org-capture-place-item ()
+  "Place the template as a new plain list item."
+  (let* ((txt (org-capture-get :template))
+	 (target-entry-p (org-capture-get :target-entry-p))
+	 ind beg end)
+    (cond
+     ((not target-entry-p)
+      ;; Insert as top-level entry, either at beginning or at end of file
+      (setq beg (point-min) end (point-max)))
+     (t
+      (setq beg (1+ (point-at-eol))
+	    end (save-excursion (outline-next-heading) (point)))))
+    (if (org-capture-get :prepend)
+	(progn
+	  (goto-char beg)
+	  (if (re-search-forward (concat "^" (org-item-re)) nil t)
+	      (progn
+		(goto-char (match-beginning 0))
+		(setq ind (org-get-indentation)))
+	    (goto-char end)
+	    (setq ind 0)))
+      (goto-char end)
+      (if (re-search-backward (concat "^" (org-item-re)) nil t)
+	  (progn
+	    (setq ind (org-get-indentation))
+	    (org-end-of-item))
+	(setq ind 0)))
+    ;; Remove common indentation
+    (setq txt (org-remove-indentation txt))
+    ;; Make sure this is indeed an item
+    (unless (string-match (concat "\\`" (org-item-re)) txt)
+      (setq txt (concat "- "
+			(mapconcat 'identity (split-string txt "\n")
+				   "\n  "))))
+    ;; Set the correct indentation, depending on context
+    (setq ind (make-string ind ?\ ))
+    (setq txt (concat ind
+		      (mapconcat 'identity (split-string txt "\n")
+				 (concat "\n" ind))))
+    ;; Insert, with surrounding empty lines
+    (org-capture-empty-lines-before)
+    (setq beg (point))
+    (insert txt)
+    (org-capture-empty-lines-after 1)
+    (setq end (point))
+    (org-capture-narrow beg (1- end))
+    (if (re-search-forward "%\\?" end t) (replace-match ""))))
+
+(defun org-capture-place-table-line ()
+  "Place the template as a table line."
+  (let* ((txt (org-capture-get :template))
+	 (target-entry-p (org-capture-get :target-entry-p))
+	 ind beg end)
+    (cond
+     ((not target-entry-p)
+      (setq beg (point-min) end (point-max)))
+     (t
+      (setq beg (1+ (point-at-eol))
+	    end (save-excursion (outline-next-heading) (point)))))
+    (if (re-search-forward org-table-dataline-regexp end t)
+	(let ((b (org-table-begin)) (e (org-table-end)))
+	  (goto-char e)
+	  (if (looking-at "[ \t]*#\\+TBLFM:")
+	      (forward-line 1))
+	  (narrow-to-region b (point)))
+      (goto-char end)
+      (insert "\n\n")
+      (narrow-to-region (1- (point)) (point)))
+    ;; We are narrowed to the table, or to an empty line if there was no table
+
+    ;; Check if the template is good
+    (if (not (string-match org-table-dataline-regexp txt))
+	(setq txt "| %?Bad template |\n"))
+
+    (if (org-capture-get :prepend)
+	(progn
+	  (goto-char (point-min))
+	  (re-search-forward org-table-hline-regexp nil t)
+	  (beginning-of-line 1)
+	  (re-search-forward org-table-dataline-regexp nil t)
+	  (beginning-of-line 1)
+	  (setq beg (point))
+	  (org-table-insert-row)
+	  (beginning-of-line 1)
+	  (delete-region (point) (1+ (point-at-eol)))
+	  (insert txt)
+	  (setq end (point)))
+      (goto-char (point-max))
+      (re-search-backward org-table-dataline-regexp nil t)
+      (beginning-of-line 1)
+      (org-table-insert-row 'below)
+      (beginning-of-line 1)
+      (delete-region (point) (1+ (point-at-eol)))
+      (setq beg (point))
+      (insert txt)
+      (setq end (point)))
+    (goto-char beg)
+    (if (re-search-forward "%\\?" end t) (replace-match ""))
+    (org-table-align)))
+
+(defun org-capture-place-plain-text ()
+  "Place the template plainly."
+  (let* ((txt (org-capture-get :template))
+	 beg end)
+    (goto-char (if (org-capture-get :prepend) (point-min) (point-max)))
+    (or (bolp) (newline))
+    (org-capture-empty-lines-before)
+    (setq beg (point))
+    (insert txt)
+    (org-capture-empty-lines-after 1)
+    (setq end (point))
+    (org-capture-narrow beg (1- end))
+    (if (re-search-forward "%\\?" end t) (replace-match ""))))
+
+(defun org-capture-narrow (beg end)
+  "Narrow, unless configuraion says not to narrow."
+  (unless (org-capture-get :unnarrowed)
+    (narrow-to-region beg end)
+    (goto-char beg)))
+
+(defun org-capture-empty-lines-before (&optional n)
+  "Arrange for the correct number of empty lines before the insertion point.
+Point will be after the empty lines, so insertion can direcetly be done."
+  (setq n (or n (org-capture-get :empty-lines) 0))
+  (let ((pos (point)))
+    (org-back-over-empty-lines)
+    (delete-region (point) pos)
+    (newline n)))
+
+(defun org-capture-empty-lines-after (&optional n)
+  "Arrange for the correct number of empty lines after the inserted string.
+Point will remain at the first line after the inserted text."
+  (setq n (or n (org-capture-get :empty-lines) 0))
+  (org-back-over-empty-lines)
+  (while (looking-at "[ \t]*\n") (replace-match ""))
+  (let ((pos (point)))
+    (newline n)
+    (goto-char pos)))
+
+(defvar org-clock-marker) ; Defined in org.el
+;;;###autoload
+(defun org-capture-insert-template-here ()
+  (let* ((template (org-capture-get :template))
+	 (type  (org-capture-get :type))
+	 beg end pp)
+    (or (bolp) (newline))
+    (setq beg (point))
+    (cond
+     ((and (eq type 'entry) (org-mode-p))
+      (org-paste-subtree nil template t))
+     ((and (memq type '(item checkitem))
+	   (org-mode-p)
+	   (save-excursion (skip-chars-backward " \t\n")
+			   (setq pp (point))
+			   (org-in-item-p)))
+      (goto-char pp)
+      (org-insert-item)
+      (skip-chars-backward " ")
+      (skip-chars-backward "-+*0123456789).")
+      (delete-region (point) (point-at-eol))
+      (setq beg (point))
+      (org-remove-indentation template)
+      (insert template)
+      (org-capture-empty-lines-after)
+      (goto-char beg)
+      (org-maybe-renumber-ordered-list)
+      (org-end-of-item)
+      (setq end (point)))
+     (t (insert template)))
+    (setq end (point))
+    (goto-char beg)
+    (if (re-search-forward "%\\?" end t)
+	(replace-match ""))))
+
+(defun org-capture-set-plist (entry)
+  "Initialize the property list from the template definition."
+  (setq org-capture-plist (copy-sequence (nthcdr 5 entry)))
+  (org-capture-put :key (car entry) :description (nth 1 entry)
+		   :target (nth 3 entry))
+  (let ((txt (nth 4 entry)) (type (or (nth 2 entry) 'entry)))
+    (when (or (not txt) (not (string-match "\\S-" txt)))
+      ;; The template may be empty or omitted for special types.
+      ;; Here we insert the default templates for such cases.
+      (cond
+       ((eq type 'item) (setq txt "- %?"))
+       ((eq type 'checkitem) (setq txt "- [ ] %?"))
+       ((eq type 'table-line) (setq txt "| %? |"))
+       ((member type '(nil entry)) (setq txt "* %?"))))
+    (org-capture-put :template txt :type type)))
+
+(defun org-capture-goto-target (&optional template-key)
+  "Go to the target location of a capture template.
+The user is queried for the template."
+  (interactive)
+  (let* (org-select-template-temp-major-mode
+	 (entry (org-capture-select-template template-key)))
+    (unless entry
+      (error "No capture emplate selected"))
+    (org-capture-set-plist entry)
+    (org-capture-set-target-location)
+    (switch-to-buffer (org-capture-get :buffer))
+    (goto-char (org-capture-get :pos))))
+
+(defun org-capture-get-indirect-buffer (&optional buffer prefix)
+  "Make an indirect buffer for a capture process.
+Use PREFIX as a prefix for the name of the indirect buffer."
+  (setq buffer (or buffer (current-buffer)))
+  (let ((n 1) (base (buffer-name buffer)) bname)
+    (setq bname (concat prefix "-" base))
+    (while (buffer-live-p (get-buffer bname))
+      (setq bname (concat prefix "-" (number-to-string (incf n)) "-" base)))
+    (condition-case nil
+        (make-indirect-buffer buffer bname 'clone)
+      (error (make-indirect-buffer buffer bname)))))
+
+
+;;; The template code
+
+(defun org-capture-select-template (&optional keys)
+  "Select a capture template.
+Lisp programs can force the template by setting KEYS to a string."
+  (when org-capture-templates
+    (if keys
+	(or (assoc keys org-capture-templates)
+	    (error "No capture template referred to by \"%s\" keys"))
+      (org-mks org-capture-templates
+	       "Select a capture template\n========================="
+	       "Template key: "
+	       '(("C" "Customize org-capture-templates"))))))
+
+(defun org-capture-fill-template (&optional template initial annotation)
+  "Fill a template and return the filled template as a string.
+The template may still contain \"%?\" for cursor positioning."
+  (setq template (or template (org-capture-get :template)))
+  (when (stringp initial)
+    (setq initial (org-no-properties initial))
+    (remove-text-properties 0 (length initial) '(read-only t) initial))
+  (let* ((buffer (org-capture-get :buffer))
+	 (file (buffer-file-name (or (buffer-base-buffer buffer) buffer)))
+	 (ct (org-capture-get :default-time))
+	 (dct (decode-time ct))
+	 (ct1
+	  (if (< (nth 2 dct) org-extend-today-until)
+	      (encode-time 0 59 23 (1- (nth 3 dct)) (nth 4 dct) (nth 5 dct))
+	    ct))
+	 (plist-p (if org-store-link-plist t nil))
+	 (v-c (and (> (length kill-ring) 0) (current-kill 0)))
+	 (v-x (or (org-get-x-clipboard 'PRIMARY)
+		  (org-get-x-clipboard 'CLIPBOARD)
+		  (org-get-x-clipboard 'SECONDARY)))
+	 (v-t (format-time-string (car org-time-stamp-formats) ct))
+	 (v-T (format-time-string (cdr org-time-stamp-formats) ct))
+	 (v-u (concat "[" (substring v-t 1 -1) "]"))
+	 (v-U (concat "[" (substring v-T 1 -1) "]"))
+	 ;; `initial' and `annotation' might habe been passed.
+	 ;; But if the property list has them, we prefer those values
+	 (v-i (or (plist-get org-store-link-plist :initial)
+		  initial
+		  (org-capture-get :initial)
+		  ""))
+	 (v-a (or (plist-get org-store-link-plist :annotation)
+		  annotation
+		  (org-capture-get :annotation)
+		  ""))
+	 ;; Is the link empty?  Then we do not want it...
+	 (v-a (if (equal v-a "[[]]") "" v-a))
+	 (clipboards (remove nil (list v-i
+				       (org-get-x-clipboard 'PRIMARY)
+				       (org-get-x-clipboard 'CLIPBOARD)
+				       (org-get-x-clipboard 'SECONDARY)
+				       v-c)))
+	 (v-A (if (and v-a
+		       (string-match
+			"\\[\\(\\[.*?\\]\\)\\(\\[.*?\\]\\)?\\]" v-a))
+		  (replace-match "[\\1[%^{Link description}]]" nil nil v-a)
+		v-a))
+	 (v-n user-full-name)
+	 (v-k (if (marker-buffer org-clock-marker)
+		  (org-substring-no-properties org-clock-heading)))
+	 (v-K (if (marker-buffer org-clock-marker)
+		  (org-make-link-string
+		   (buffer-file-name (marker-buffer org-clock-marker))
+		   org-clock-heading)))
+	 v-I
+	 (org-startup-folded nil)
+	 (org-inhibit-startup t)
+	 org-time-was-given org-end-time-was-given x
+	 prompt completions char time pos default histvar)
+
+    (setq org-store-link-plist
+	  (plist-put org-store-link-plist :annotation v-a)
+	  org-store-link-plist
+	  (plist-put org-store-link-plist :initial v-i))
+
+    (unless template (setq template "") (message "No template") (ding)
+	    (sit-for 1))
+    (save-window-excursion
+      (delete-other-windows)
+      (switch-to-buffer (get-buffer-create "*Capture*"))
+      (insert template)
+      (goto-char (point-min))
+      (org-capture-steal-local-variables buffer)
+      ;; Simple %-escapes
+      (while (re-search-forward "%\\([tTuUaiAcxkKI]\\)" nil t)
+	(unless (org-capture-escaped-%)
+	  (when (and initial (equal (match-string 0) "%i"))
+	    (save-match-data
+	      (let* ((lead (buffer-substring
+			    (point-at-bol) (match-beginning 0))))
+		(setq v-i (mapconcat 'identity
+				     (org-split-string initial "\n")
+				     (concat "\n" lead))))))
+	  (replace-match
+	   (or (eval (intern (concat "v-" (match-string 1)))) "")
+	   t t)))
+
+      ;; %[] Insert contents of a file.
+      (goto-char (point-min))
+      (while (re-search-forward "%\\[\\(.+\\)\\]" nil t)
+	(unless (org-capture-escaped-%)
+	  (let ((start (match-beginning 0))
+		(end (match-end 0))
+		(filename (expand-file-name (match-string 1))))
+	    (goto-char start)
+	    (delete-region start end)
+	    (condition-case error
+		(insert-file-contents filename)
+	      (error (insert (format "%%![Couldn't insert %s: %s]"
+				     filename error)))))))
+      ;; %() embedded elisp
+      (goto-char (point-min))
+      (while (re-search-forward "%\\((.+)\\)" nil t)
+	(unless (org-capture-escaped-%)
+	  (goto-char (match-beginning 0))
+	  (let ((template-start (point)))
+	    (forward-char 1)
+	    (let ((result
+		   (condition-case error
+		       (eval (read (current-buffer)))
+		     (error (format "%%![Error: %s]" error)))))
+	      (delete-region template-start (point))
+	      (insert result)))))
+
+      ;; From the property list
+      (when plist-p
+	(goto-char (point-min))
+	(while (re-search-forward "%\\(:[-a-zA-Z]+\\)" nil t)
+	  (unless (org-capture-escaped-%)
+	    (and (setq x (or (plist-get org-store-link-plist
+					(intern (match-string 1))) ""))
+		 (replace-match x t t)))))
+
+      ;; Turn on org-mode in temp buffer, set local variables
+      ;; This is to support completion in interactive prompts
+      (let ((org-inhibit-startup t)) (org-mode))
+      ;; Interactive template entries
+      (goto-char (point-min))
+      (while (re-search-forward "%^\\({\\([^}]*\\)}\\)?\\([gGtTuUCLp]\\)?"
+				nil t)
+	(unless (org-capture-escaped-%)
+	  (setq char (if (match-end 3) (match-string 3))
+		prompt (if (match-end 2) (match-string 2)))
+	  (goto-char (match-beginning 0))
+	  (replace-match "")
+	  (setq completions nil default nil)
+	  (when prompt
+	    (setq completions (org-split-string prompt "|")
+		  prompt (pop completions)
+		  default (car completions)
+		  histvar (intern (concat
+				   "org-capture-template-prompt-history::"
+				   (or prompt "")))
+		  completions (mapcar 'list completions)))
+	  (cond
+	   ((member char '("G" "g"))
+	    (let* ((org-last-tags-completion-table
+		    (org-global-tags-completion-table
+		     (if (equal char "G")
+			 (org-agenda-files)
+		       (and file (list file)))))
+		   (org-add-colon-after-tag-completion t)
+		   (ins (org-icompleting-read
+			 (if prompt (concat prompt ": ") "Tags: ")
+			 'org-tags-completion-function nil nil nil
+			 'org-tags-history)))
+	      (setq ins (mapconcat 'identity
+				   (org-split-string
+				    ins (org-re "[^[:alnum:]_@]+"))
+				       ":"))
+	      (when (string-match "\\S-" ins)
+		(or (equal (char-before) ?:) (insert ":"))
+		(insert ins)
+		(or (equal (char-after) ?:) (insert ":")))))
+	   ((equal char "C")
+	    (cond ((= (length clipboards) 1) (insert (car clipboards)))
+		  ((> (length clipboards) 1)
+		   (insert (read-string "Clipboard/kill value: "
+					(car clipboards) '(clipboards . 1)
+					(car clipboards))))))
+	   ((equal char "L")
+	    (cond ((= (length clipboards) 1)
+		   (org-insert-link 0 (car clipboards)))
+		  ((> (length clipboards) 1)
+		   (org-insert-link 0 (read-string "Clipboard/kill value: "
+						   (car clipboards)
+						   '(clipboards . 1)
+						   (car clipboards))))))
+	   ((equal char "p")
+	    (let*
+		((prop (org-substring-no-properties prompt))
+		 (pall (concat prop "_ALL"))
+		 (allowed
+		  (with-current-buffer
+		      (get-buffer (file-name-nondirectory file))
+		    (or (cdr (assoc pall org-file-properties))
+			(cdr (assoc pall org-global-properties))
+			(cdr (assoc pall org-global-properties-fixed)))))
+		 (existing (with-current-buffer
+			       (get-buffer (file-name-nondirectory file))
+			     (mapcar 'list (org-property-values prop))))
+		 (propprompt (concat "Value for " prop ": "))
+		 (val (if allowed
+			  (org-completing-read
+			   propprompt
+			   (mapcar 'list (org-split-string allowed
+							   "[ \t]+"))
+			   nil 'req-match)
+			(org-completing-read-no-i propprompt
+						  existing nil nil
+						  "" nil ""))))
+	      (org-set-property prop val)))
+	   (char
+	    ;; These are the date/time related ones
+	    (setq org-time-was-given (equal (upcase char) char))
+	    (setq time (org-read-date (equal (upcase char) "U") t nil
+				      prompt))
+	    (org-insert-time-stamp time org-time-was-given
+				   (member char '("u" "U"))
+				   nil nil (list org-end-time-was-given)))
+	   (t
+	    (let (org-completion-use-ido)
+	      (insert (org-completing-read-no-i
+		       (concat (if prompt prompt "Enter string")
+			       (if default (concat " [" default "]"))
+			       ": ")
+		       completions nil nil nil histvar default)))))))
+      ;; Make sure there are no empty lines before the text, and that
+      ;; it ends with a newline character
+      (goto-char (point-min))
+      (while (looking-at "[ \t]*\n") (replace-match ""))
+      (if (re-search-forward "[ \t\n]*\\'" nil t) (replace-match "\n"))
+      ;; Return the expanded tempate and kill the temporary buffer
+      (untabify (point-min) (point-max))
+      (set-buffer-modified-p nil)
+      (prog1 (buffer-string) (kill-buffer (current-buffer))))))
+
+(defun org-capture-escaped-% ()
+  "Check if % was escaped - if yes, unescape it now."
+  (if (equal (char-before (match-beginning 0)) ?\\)
+      (progn
+	(delete-region (1- (match-beginning 0)) (match-beginning 0))
+	t)
+    nil))
+
+;;;###autoload
+(defun org-capture-import-remember-templates ()
+  "Set org-capture-templates to be similar to `org-remember-templates'."
+  (interactive)
+  (when (and (yes-or-no-p
+	      "Import old remember templates into org-capture-templates? ")
+	     (yes-or-no-p
+	      "Note that this will remove any templates currently defined in `org-capture-templates'.  Do you still want to go ahead? "))
+    (setq org-capture-templates
+	  (mapcar
+	   (lambda (entry)
+	     (let ((desc (car entry))
+		   (key (char-to-string (nth 1 entry)))
+		   (template (nth 2 entry))
+		   (file (or (nth 3 entry) org-default-notes-file))
+		   (position (nth 4 entry))
+		   (type 'entry)
+		   (prepend org-reverse-note-order)
+		   immediate target)
+	       (cond
+		((member position '(top bottom))
+		 (setq target (list 'file file)
+		       prepend (eq position 'top)))
+		((eq position 'date-tree)
+		 (setq target (list 'file+datetree file)
+		       prepend nil))
+		(t (setq target
+			 (list 'file+headline file
+			       (or position org-remember-default-headline)))))
+
+	       (when (string-match "%!" template)
+		 (setq template (replace-match "" t t template)
+		       immediate t))
+
+	       (append (list key desc type target template)
+		       (if prepend '(:prepend t))
+		       (if immediate '(:immediate-finish t)))))
+
+	   org-remember-templates))))
+
+(provide 'org-capture)
+
+;; arch-tag: 986bf41b-8ada-4e28-bf20-e8388a7205a0
+
+;;; org-capture.el ends here
+
+

lisp/org-compat.el

@@ -132,6 +132,12 @@ If DELETE is non-nil, delete all those overlays."
           (if delete (delete-overlay ov) (push ov found))))
     found))
 
+(defun org-get-x-clipboard (value)
+  "Get the value of the x clipboard, compatible with XEmacs, and GNU Emacs 21."
+  (if (eq window-system 'x)
+      (let ((x (org-get-x-clipboard-compat value)))
+	(if x (org-no-properties x)))))
+
 ;; Miscellaneous functions
 
 (defun org-add-hook (hook function &optional append local)

lisp/org-datetree.el

@@ -36,8 +36,8 @@
 (defvar org-datetree-base-level 1
   "The level at which years should be placed in the date tree.
 This is normally one, but if the buffer has an entry with a DATE_TREE
-property, the date tree will become a subtree under that entry, so the
-base level will be properly adjusted.")
+property (any value), the date tree will become a subtree under that entry,
+so the base level will be properly adjusted.")
 
 ;;;###autoload
 (defun org-datetree-find-date-create (date &optional keep-restriction)

lisp/org-entities.el

@@ -506,6 +506,10 @@ Kind can be any of `latex', `html', `ascii', `latin1', or `utf8'."
 
 (provide 'org-entities)
 
+;; Local variables:
+;; coding: utf-8
+;; End:
+
 ;; arch-tag: e6bd163f-7419-4009-9c93-a74623016424
 
 ;;; org-entities.el ends here

lisp/org-exp.el

@@ -2145,7 +2145,7 @@ INDENT was the original indentation of the block."
 		      (org-add-props (concat "<programlisting><![CDATA["
 					     rtn
 					     "]]></programlisting>\n")
-			  '(org-protected t))
+			  '(org-protected t org-example t))
 		      "#+END_DOCBOOK\n"))
 	     ((eq backend 'html)
 	      ;; We are exporting to HTML
@@ -2215,7 +2215,7 @@ INDENT was the original indentation of the block."
 						   cont rpllbl fmt)))
 	      (if (string-match "\\(\\`<[^>]*>\\)\n" rtn)
 		  (setq rtn (replace-match "\\1" t nil rtn)))
-	      (concat "\n#+BEGIN_HTML\n" (org-add-props rtn '(org-protected t)) "\n#+END_HTML\n\n"))
+	      (concat "\n#+BEGIN_HTML\n" (org-add-props rtn '(org-protected t org-example t)) "\n#+END_HTML\n\n"))
 	     ((eq backend 'latex)
 	      (setq rtn (org-export-number-lines rtn 'latex 0 0 num cont rpllbl fmt))
 	      (concat "#+BEGIN_LaTeX\n"
@@ -2239,7 +2239,7 @@ INDENT was the original indentation of the block."
                                rtn "\\end{lstlisting}\n")
                             (concat (car org-export-latex-verbatim-wrap)
                                     rtn (cdr org-export-latex-verbatim-wrap)))
-			  '(org-protected t))
+			  '(org-protected t org-example t))
 		      "#+END_LaTeX\n"))
 	     ((eq backend 'ascii)
 	      ;; This is not HTML or LaTeX, so just make it an example.
@@ -2253,7 +2253,7 @@ INDENT was the original indentation of the block."
 			    (org-split-string rtn "\n")
 			    "\n")
 			   "\n")
-			  '(org-protected t))
+			  '(org-protected t org-example t))
 		      "#+END_ASCII\n"))))
       (org-add-props rtn nil 'original-indentation indent))))
 

lisp/org-html.el

@@ -2146,11 +2146,17 @@ If there are links in the string, don't modify these."
 (defvar local-list-indent)
 (defvar local-list-type)
 (defun org-export-html-close-lists-maybe (line)
+  "Close local lists based on the original indentation of the line."
   (let* ((rawhtml (and in-local-list
-		       (get-text-property 0 'org-protected line)))
+		       (get-text-property 0 'org-protected line)
+		       (not (get-text-property 0 'org-example line))))
+	 ;; rawhtml means: This was between #+begin_html..#+end_html
+	 ;; originally, thus it excludes stuff that was a source code example
+	 ;; Actually, this code seems wrong, I don't know why it works, but
+	 ;; it seems to work.... So keep it like this for now.
          (ind (if rawhtml
 		  (org-get-indentation line)
-		(or (get-text-property 0 'original-indentation line))))
+		(get-text-property 0 'original-indentation line)))
 	 didclose)
     (when ind
       (while (and in-local-list

lisp/org-mks.el

@@ -0,0 +1,123 @@
+;;; org-mks.el --- Multi-key-selection for Org-mode
+
+;; Copyright (C) 2010  Free Software Foundation, Inc.
+
+;; Author: Carsten Dominik <carsten at orgmode dot org>
+;; Keywords: outlines, hypermedia, calendar, wp
+;; Homepage: http://orgmode.org
+;; Version: 6.36trans
+;;
+;; This file is part of GNU Emacs.
+;;
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+
+(defun org-mks (table title &optional prompt specials)
+  "Select a member of an alist with multiple keys.
+TABLE is the alist which should contain entries where the car is a string.
+There should be two types of entries.
+
+1. prefix descriptions like (\"a\" \"Description\")
+   This indicates that `a' is a prefix key for multi-letter selection, and
+   that there are entries following with keys like \"ab\", \"ax\"...
+
+2. Selectable members must have more than two elements, with the first
+   being the string of keys that lead to selecting it, and the second a
+   short description string of the item.
+
+The command will then make a temporary buffer listing all entries
+that can be selected with a single key, and all the sinke key
+prefixes.  When you press the key for a single-letter enty, it is selected.
+When you press a prefix key, the commands (and maybe further prefixes)
+under this key will be shown and offered for selection.
+
+TITLE will be placed over the selection in the temporary buffer,
+PROMPT will be used when prompting for a key.  SPECIAL is an alist with
+also (\"key\" \"description\") entries.  When they are selected, 
+
+
+"
+  (setq prompt (or prompt "Select: "))
+  (let (tbl orig-table dkey ddesc des-keys allowed-keys current prefix rtn)
+    (save-window-excursion
+      (org-switch-to-buffer-other-window "*Org Select*")
+      (setq orig-table table)
+      (catch 'exit
+	(while t
+	  (erase-buffer)
+	  (insert title "\n\n")
+	  (setq tbl table
+		des-keys nil
+		allowed-keys nil)
+	  (setq prefix (if current (concat current " ") ""))
+	  (while tbl
+	    (cond
+	     ((and (= 2 (length (car tbl))) (= (length (caar tbl)) 1))
+	      ;; This is a description on this level
+	      (setq dkey (caar tbl) ddesc (cadar tbl))
+	      (pop tbl)
+	      (push dkey des-keys)
+	      (push dkey allowed-keys)
+	      (insert prefix "[" dkey "]" "..." "  " ddesc "..." "\n")
+	      ;; Skip keys which are below this prefix
+	      (setq re (concat "\\`" (regexp-quote dkey)))
+	      (while (and tbl (string-match re (caar tbl))) (pop tbl)))
+	     ((= 2 (length (car tbl)))
+	      ;; Not yet a usable description, skip it
+	      )
+	     (t
+	      ;; usable entry on this level
+	      (insert prefix "[" (caar tbl) "]" "     " (nth 1 (car tbl)) "\n")
+	      (push (caar tbl) allowed-keys)
+	      (pop tbl))))
+	  (when specials
+	    (insert "-------------------------------------------------------------------------------\n")
+	    (let ((sp specials))
+	      (while sp
+		(insert (format "[%s]     %s\n"
+				(caar sp) (nth 1 (car sp))))
+		(push (caar sp) allowed-keys)
+		(pop sp))))
+	  (push "\C-g" allowed-keys)
+	  (goto-char (point-min))
+	  (if (not (pos-visible-in-window-p (point-max)))
+	      (org-fit-window-to-buffer))
+	  (message prompt)
+	  (setq pressed (char-to-string (read-char-exclusive)))
+	  (while (not (member pressed allowed-keys))
+	    (message "Invalid key `%s'" pressed) (sit-for 1)
+	    (message prompt)
+	    (setq pressed (char-to-string (read-char-exclusive))))
+	  (if (equal pressed "\C-g") (error "Abort"))
+	  (if (assoc pressed specials) (throw 'exit (setq rtn pressed)))
+	  (unless (member pressed des-keys)
+	    (throw 'exit (setq rtn (rassoc (cdr (assoc pressed table))
+					   orig-table))))
+	  (setq current (concat current pressed))
+	  (setq table (mapcar 
+		       (lambda (x)
+			 (if (and (> (length (car x)) 1)
+				  (equal (substring (car x) 0 1) pressed))
+			     (cons (substring (car x) 1) (cdr x))
+			   nil))
+		       table))
+	  (setq table (remove nil table)))))
+    (kill-buffer "*Org Select*")
+    rtn))
+
+(provide 'org-mks)
+
+;; arch-tag: 4ea90d0e-c6e4-4684-bd61-baf878712f9f
+
+;;; org-mks.el ends here

lisp/org-remember.el

@@ -392,12 +392,6 @@ RET at beg-of-buf -> Append to file as level 2 headline
 			 char0))))))
       (cddr (assoc char templates)))))
 
-(defun org-get-x-clipboard (value)
-  "Get the value of the x clipboard, compatible with XEmacs, and GNU Emacs 21."
-  (if (eq window-system 'x)
-      (let ((x (org-get-x-clipboard-compat value)))
-	(if x (org-no-properties x)))))
-
 ;;;###autoload
 (defun org-remember-apply-template (&optional use-char skip-interactive)
   "Initialize *remember* buffer with template, invoke `org-mode'.

lisp/org.el

@@ -3611,6 +3611,11 @@ If TABLE-TYPE is non-nil, also check for table.el-type tables."
 		'(org-remember-insinuate org-remember-annotation
    org-remember-apply-template org-remember org-remember-handler)))
 
+(eval-and-compile
+  (org-autoload "org-capture"
+		'(org-capture org-capture-insert-template-here
+                  org-capture-import-remember-templates)))
+
 ;; Autoload org-clock.el
 
 
@@ -4317,7 +4322,11 @@ means to push this value onto the list in the variable.")
 	    org-complex-heading-regexp-format
 	    (concat "^\\(\\*+\\)[ \t]+\\(?:\\("
 		    (mapconcat 'regexp-quote org-todo-keywords-1 "\\|")
-		    "\\)\\>\\)?\\(?:[ \t]*\\(\\[#.\\]\\)\\)?[ \t]*\\(%s\\)"
+		    "\\)\\>\\)?"
+		    "\\(?:[ \t]*\\(\\[#.\\]\\)\\)?"
+		    "\\(?:[ \t]*\\(?:\\[[0-9%%/]+\\]\\)\\)?" ;; stats cookie
+		    "[ \t]*\\(%s\\)"
+		    "\\(?:[ \t]*\\(?:\\[[0-9%%/]+\\]\\)\\)?" ;; stats cookie
 		    "\\(?:[ \t]+\\(:[[:alnum:]_@:]+:\\)\\)?[ \t]*$")
 	    org-nl-done-regexp
 	    (concat "\n\\*+[ \t]+"
@@ -4571,10 +4580,8 @@ The following commands are available:
 		 'org-block-todo-from-checkboxes))
 
   ;; Comment characters
-  ;; (org-set-local 'comment-start "#")
+  (org-set-local 'comment-start "#")
   (org-set-local 'comment-padding " ")
-  (modify-syntax-entry ?# "<")
-  ;; (modify-syntax-entry ?\n ">")
 
   ;; Align options lines
   (org-set-local
@@ -13777,7 +13784,7 @@ completion."
     (skip-chars-forward " \t")
     (run-hook-with-args 'org-property-changed-functions key nval)))
 
-(defun org-find-olp (path)
+(defun org-find-olp (path &optional this-buffer)
   "Return a marker pointing to the entry at outline path OLP.
 If anything goes wrong, throw an error.
 You can wrap this call to cathc the error like this:
@@ -13787,9 +13794,12 @@ You can wrap this call to cathc the error like this:
     (error (nth 1 msg)))
 
 The return value will then be either a string with the error message,
-or a marker if everyhing is OK."
-  (let* ((file (pop path))
-	 (buffer (find-file-noselect file))
+or a marker if everyhing is OK.
+
+If THIS-BUFFER is set, the putline path does not contain a file,
+only headings."
+  (let* ((file (if this-buffer buffer-file-name (pop path)))
+	 (buffer (if this-buffer (current-buffer) (find-file-noselect file)))
 	 (level 1)
 	 (lmin 1)
 	 (lmax 1)
@@ -14684,20 +14694,18 @@ days in order to avoid rounding problems."
 (defun org-time-string-to-seconds (s)
   (org-float-time (org-time-string-to-time s)))
 
-(defun org-time-string-to-absolute (s &optional daynr prefer show-all ignore-cyclic)
+(defun org-time-string-to-absolute (s &optional daynr prefer show-all)
   "Convert a time stamp to an absolute day number.
-If there is a specifier for a cyclic time stamp, get the closest date to
+If there is a specifyer for a cyclic time stamp, get the closest date to
 DAYNR.
 PREFER and SHOW-ALL are passed through to `org-closest-date'.
-the variable date is bound by the calendar when this is called.
-IGNORE-CYCLIC ignores cyclic repeaters so the returned absolute date
-is based on the original date."
+the variable date is bound by the calendar when this is called."
   (cond
    ((and daynr (string-match "\\`%%\\((.*)\\)" s))
     (if (org-diary-sexp-entry (match-string 1 s) "" date)
 	daynr
       (+ daynr 1000)))
-   ((and (not ignore-cyclic) daynr (string-match "\\+[0-9]+[dwmy]" s))
+   ((and daynr (string-match "\\+[0-9]+[dwmy]" s))
     (org-closest-date s (if (and (boundp 'daynr) (integerp daynr)) daynr
 			  (time-to-days (current-time))) (match-string 0 s)
 			  prefer show-all))
@@ -14879,7 +14887,7 @@ If the cursor is on the year, change the year.  If it is on the month or
 the day, change that.
 With prefix ARG, change by that many units."
   (interactive "p")
-  (org-timestamp-change (prefix-numeric-value arg)))
+  (org-timestamp-change (prefix-numeric-value arg) nil 'updown))
 
 (defun org-timestamp-down (&optional arg)
   "Decrease the date item at the cursor by one.
@@ -14887,7 +14895,7 @@ If the cursor is on the year, change the year.  If it is on the month or
 the day, change that.
 With prefix ARG, change by that many units."
   (interactive "p")
-  (org-timestamp-change (- (prefix-numeric-value arg))))
+  (org-timestamp-change (- (prefix-numeric-value arg)) nil 'updown))
 
 (defun org-timestamp-up-day (&optional arg)
   "Increase the date in the time stamp by one day.
@@ -14896,7 +14904,7 @@ With prefix ARG, change that many days."
   (if (and (not (org-at-timestamp-p t))
 	   (org-on-heading-p))
       (org-todo 'up)
-    (org-timestamp-change (prefix-numeric-value arg) 'day)))
+    (org-timestamp-change (prefix-numeric-value arg) 'day 'updown)))
 
 (defun org-timestamp-down-day (&optional arg)
   "Decrease the date in the time stamp by one day.
@@ -14905,7 +14913,7 @@ With prefix ARG, change that many days."
   (if (and (not (org-at-timestamp-p t))
 	   (org-on-heading-p))
       (org-todo 'down)
-    (org-timestamp-change (- (prefix-numeric-value arg)) 'day)))
+    (org-timestamp-change (- (prefix-numeric-value arg)) 'day) 'updown))
 
 (defun org-at-timestamp-p (&optional inactive-ok)
   "Determine if the cursor is in or at a timestamp."
@@ -14950,7 +14958,7 @@ With prefix ARG, change that many days."
       (message "Timestamp is now %sactive"
 	       (if (equal (char-after beg) ?<) "" "in")))))
 
-(defun org-timestamp-change (n &optional what)
+(defun org-timestamp-change (n &optional what updown)
   "Change the date in the time stamp at point.
 The date will be changed by N times WHAT.  WHAT can be `day', `month',
 `year', `minute', `second'.  If WHAT is not given, the cursor position
@@ -14981,8 +14989,10 @@ in the timestamp determines what will be changed."
       (if (string-match "^.\\{10\\}.*?[0-9]+:[0-9][0-9]" ts)
 	  (setq with-hm t))
       (setq time0 (org-parse-time-string ts))
-      (when (and (eq org-ts-what 'minute)
-		 (eq current-prefix-arg nil))
+      (when (and updown
+		 (eq org-ts-what 'minute)
+		 (not current-prefix-arg))
+	;; This looks like s-up and s-down.  Change by one rounding step.
 	(setq n (* dm (cond ((> n 0) 1) ((< n 0) -1) (t 0))))
 	(when (not (= 0 (setq rem (% (nth 1 time0) dm))))
 	  (setcar (cdr time0) (+ (nth 1 time0)